Hebrew Calendar Conversion Sample Code in VB.Net

HebCal is a VB.Net module to demonstrate how to convert a Hebrew date into the Gregorian date.

There are many books and articles that go into depth explaining the history, math and theory of the Hebrew calendar. My goal here is specifically to demonstrate how to apply these rules. In doing so, I tried to use very generic code without using any fancy language-specific features.

Much of the information is based on the excellent website Hebrew Calendar Science and Myths by Remy Landau, and the book, Glimpse of Light by Dr. J. Shamroth.

If you have any questions or comments, please contact me at srabra@netzero.net.

Public Module HebCal
  ' This code demonstrates how to convert a Hebrew date into a
  ' Gregorian date. The code is written in VB.Net, but I purposely
  ' used very generic features so it would be easy to translate
  ' this into other languages. Also, I avoided using many
  ' optimizations in order to make the logic clearer.
  '
  ' These functions assume that all the current rules of the
  ' Hebrew calendar were always in existence (which is not true
  ' since the Hebrew calendar was not always fixed) and all the
  ' current rules of the Gregorian calendar were always in existence
  ' (which is not true).

  ' Here is a very brief description of the Hebrew calendar.
  '
  ' The Hebrew calendar is a lunisolar calendar.  This means that
  ' the months are in sync with the moon and the years stay in sync
  ' with the sun.  A solar year is approximately 365.25 days.  A
  ' lunar month is approximately 29.5 days.  Twelve lunar months is
  ' approximately 354 days (12 * 29.5=354).  Thus, a lunar year of
  ' twelve months is approximately 11.25 days shorter than the solar year.
  ' To make up for this shortfall, the Hebrew calendar adds a thirteenth
  ' month to seven years over a nineteen year period. Therefore, over
  ' a nineteen year period, the Hebrew calendar is approximately the
  ' same length as a nineteen year solar calendar.
  '
  ' In order to understand this code, you must know the following
  ' terms:
  '   Molad - new moon. Hebrew months start around the day of the
  '           new moon
  '   Chalakim - 1 / 1080 of an hour or 3 1/3 seconds
  '   Tishrei - the first month of the Hebrew year (at least for
  '             these calculations)
  '   Rosh Hashanah - The Jewish new year which starts on Tishrei 1.
  '
  ' The Hebrew calendar assumes the period of time between one new
  ' moon to the next is 29 days, 12 hours and 793 chalakim. The first
  ' molad after creation occurred on Monday, September, 7th -3760 at 5
  ' hours and 204 chalakim.  Technically, the Gregorian date would be
  ' in the year 3761 BCE because there was no year 0 in the Gregorian
  ' calendar, but we will use the year of -3760.

  ' Sample Usage:
  '    ' Converts AdarB/7/5765 to 4/6/2005
  '    MsgBox(HebCal.HebToGreg(5765, 7, 26))
  '    ' Converts 4/6/2005 to AdarB/7/5765.  The function will return
  '    ' a string of "07/26/5765" and nYearH, nMonthH, hDateH will get
  '    ' set to 5765, 7, 26
  '    MsgBox(HebCal.GregToHeb(#04/06/2005#, nYearH, nMonthH, nDateH))

  '

  ' This function returns how many months there has been from the
  ' first Molad until the beginning of the year nYearH
  Public Function MonSinceFirstMolad(ByVal nYearH As Integer) _
                  As Integer
    Dim nMonSinceFirstMolad As Integer

    ' A shortcut to this function can simply be the following formula
    '   Return Int(((235 * nYearH) - 234) / 19)
    ' This formula is found in Remy Landau's website and he
    ' attributes it to Wolfgang Alexander Shochen. I will use a less
    ' optimized function which I believe shows the underlying logic
    ' better.

    ' count how many months there has been in all years up to last
    ' year. The months of this year hasn't happened yet.
    nYearH -= 1

    ' In the 19 year cycle, there will always be 235 months. That
    ' would be 19 years times 12 months plus 7 extra month for the
    ' leap years. (19 * 12) + 7 = 235.

    ' Get how many 19 year cycles there has been and multiply it by
    ' 235
    nMonSinceFirstMolad = Int(nYearH / 19) * 235
    ' Get the remaining years after the last complete 19 year cycle
    nYearH = nYearH Mod 19
    ' Add 12 months for each of those years
    nMonSinceFirstMolad += 12 * nYearH
    ' Add the extra months to account for the leap years
    If nYearH >= 17 Then
      nMonSinceFirstMolad += 6
    ElseIf nYearH >= 14 Then
      nMonSinceFirstMolad += 5
    ElseIf nYearH >= 11 Then
      nMonSinceFirstMolad += 4
    ElseIf nYearH >= 8 Then
      nMonSinceFirstMolad += 3
    ElseIf nYearH >= 6 Then
      nMonSinceFirstMolad += 2
    ElseIf nYearH >= 3 Then
      nMonSinceFirstMolad += 1
    End If
    Return nMonSinceFirstMolad
  End Function

  ' This function returns if a given year is a leap year.
  Public Function IsLeapYear(ByVal nYearH As Integer) As Boolean
    Dim nYearInCycle As Integer

    ' Find out which year we are within the cycle.  The 19th year of
    ' the cycle will return 0
    nYearInCycle = nYearH Mod 19
    Return nYearInCycle = 3 Or _
           nYearInCycle = 6 Or _
           nYearInCycle = 8 Or _
           nYearInCycle = 11 Or _
           nYearInCycle = 14 Or _
           nYearInCycle = 17 Or _
           nYearInCycle = 0
  End Function

  ' This function figures out the Gregorian Date that corresponds to
  ' the first day of Tishrei, the first month of the Hebrew
  ' calendar, for a given Hebrew year.
  Public Function Tishrei1(ByVal nYearH As Integer) As Date
    Dim nMonthsSinceFirstMolad As Integer
    Dim nChalakim As Integer
    Dim nHours As Integer
    Dim nDays As Integer
    Dim nDayOfWeek As Integer
    Dim dTishrei1 As Date

    ' We want to calculate how many days, hours and chalakim it has
    ' been from the time of 0 days, 0 hours and 0 chalakim to the
    ' molad at the beginning of year nYearH.
    '
    ' The period between one new moon to the next is 29 days, 12
    ' hours and 793 chalakim. We must multiply that by the amount
    ' of months that transpired since the first molad. Then we add
    ' the time of the first molad (Monday, 5 hours and 204 chalakim)
    nMonthsSinceFirstMolad = MonSinceFirstMolad(nYearH)
    nChalakim = 793 * nMonthsSinceFirstMolad
    nChalakim += 204
    ' carry the excess Chalakim over to the hours
    nHours = Int(nChalakim / 1080)
    nChalakim = nChalakim Mod 1080

    nHours += nMonthsSinceFirstMolad * 12
    nHours += 5
    ' carry the excess hours over to the days
    nDays = Int(nHours / 24)
    nHours = nHours Mod 24

    nDays += 29 * nMonthsSinceFirstMolad
    nDays += 2

    ' figure out which day of the week the molad occurs.
    ' Sunday = 1, Moday = 2 ..., Shabbos = 0
    nDayOfWeek = nDays Mod 7

    ' In a perfect world, Rosh Hashanah would be on the day of the
    ' molad. The Hebrew calendar makes four exceptions where we
    ' push off Rosh Hashanah one or two days. This is done to
    ' prevent three situation. Without explaining why, the three
    ' situations are:
    '   1) We don't want Rosh Hashanah to come out on Sunday,
    '      Wednesday or Friday
    '   2) We don't want Rosh Hashanah to be on the day of the
    '      molad if the molad occurs after the beginning of 18th
    '      hour.
    '   3) We want to limit years to specific lengths.  For non-leap
    '      years, we limit it to either 353, 354 or 355 days.  For
    '      leap years, we limit it to either 383, 384 or 385 days.
    '      If setting Rosh Hashanah to the day of the molad will
    '      cause this year, or the previous year to fall outside
    '      these lengths, we push off Rosh Hashanah to get the year
    '      back to a valid length.
    ' This code handles these exceptions.

    If Not IsLeapYear(nYearH) And _
       nDayOfWeek = 3 And _
       (nHours * 1080) + nChalakim >= _
       (9 * 1080) + 204 Then
      ' This prevents the year from being 356 days. We have to push
      ' Rosh Hashanah off two days because if we pushed it off only
      ' one day, Rosh Hashanah would comes out on a Wednesday. Check
      ' the Hebrew year 5745 for an example.
      nDayOfWeek = 5
      nDays += 2
    ElseIf IsLeapYear(nYearH - 1) And _
           nDayOfWeek = 2 And _
           (nHours * 1080) + nChalakim >= _
           (15 * 1080) + 589 Then
      ' This prevents the previous year from being 382 days. Check
      ' the Hebrew Year 5766 for an example. If Rosh Hashanah was not
      ' pushed off a day then 5765 would be 382 days
      nDayOfWeek = 3
      nDays += 1
    Else
      ' see rule 2 above. Check the Hebrew year 5765 for an example
      If nHours >= 18 Then
        nDayOfWeek += 1
        nDayOfWeek = nDayOfWeek Mod 7
        nDays += 1
      End If
      ' see rule 1 above. Check the Hebrew year 5765 for an example
      If nDayOfWeek = 1 Or _
         nDayOfWeek = 4 Or _
         nDayOfWeek = 6 Then
        nDayOfWeek += 1
        nDayOfWeek = nDayOfWeek Mod 7
        nDays += 1
      End If
    End If

    ' Here we want to add nDays to creation
    '    dTishrie1 = creation + nDays
    ' Unfortunately, VB.Net doesn't handle negative years very well.
    ' I therefore picked a Random date (1/1/1900) and figured out how
    ' many days it is after the creation (2067025). Then I subtracted
    ' 2067025 from nDays.
    nDays -= 2067025
    dTishrei1 = #1/1/1900# ' 2067025 days after creation
    dTishrei1 = dTishrei1.AddDays(nDays)
    Return dTishrei1
  End Function

  ' This function gets the length of a Hebrew year.
  Public Function LengthOfYear(ByVal nYearH As Integer) As Integer
    Dim dThisTishrei1 As Date
    Dim dNextTishrei1 As Date
    Dim diff As TimeSpan

    ' subtract the date of this year from the date of next year
    dThisTishrei1 = Tishrei1(nYearH)
    dNextTishrei1 = Tishrei1(nYearH + 1)
    diff = dNextTishrei1.Subtract(dThisTishrei1)
    Return diff.Days
  End Function

  ' This function converts a Hebrew date into the Gregorian date
  ' nYearH - is the Hebrew year
  ' nMonth - Tishrei=1
  '          Cheshvan=2
  '          Kislev=3
  '          Teves=4
  '          Shevat=5
  '          Adar A=6 (only valid on leap years)
  '          Adar=7   (Adar B for leap years)
  '          Nisan=8
  '          Iyar=9
  '          Sivan=10
  '          Tamuz=11
  '          Av=12
  '          Elul=13
  Public Function HebToGreg(ByVal nYearH As Integer, _
                            ByVal nMonthH As Integer, _
                            ByVal nDateH As Integer) As Date
    Dim nLengthOfYear As Integer
    Dim bLeap As Boolean
    Dim dGreg As Date
    Dim nMonth As Integer
    Dim nMonthLen As Integer
    Dim bHaser As Boolean
    Dim bShalem As Boolean

    bLeap = IsLeapYear(nYearH)
    nLengthOfYear = LengthOfYear(nYearH)

    ' The regular length of a non-leap year is 354 days.
    ' The regular length of a leap year is 384 days.
    ' On regular years, the length of the months are as follows
    '   Tishrei (1)   30
    '   Cheshvan(2)   29
    '   Kislev  (3)   30
    '   Teves   (4)   29
    '   Shevat  (5)   30
    '   Adar A  (6)   30     (only valid on leap years)
    '   Adar    (7)   29     (Adar B for leap years)
    '   Nisan   (8)   30
    '   Iyar    (9)   29
    '   Sivan   (10)  30
    '   Tamuz   (11)  29
    '   Av      (12)  30
    '   Elul    (13)  29
    ' If the year is shorter by one less day, it is called a haser
    ' year. Kislev on a haser year has 29 days. If the year is longer
    ' by one day, it is called a shalem year. Cheshvan on a shalem
    ' year is 30 days.
    bHaser = nLengthOfYear = 353 Or nLengthOfYear = 383
    bShalem = nLengthOfYear = 355 Or nLengthOfYear = 385

    ' get the date for Tishrei 1
    dGreg = Tishrei1(nYearH)
    ' Now count up days within the year
    For nMonth = 1 To nMonthH - 1
      Select Case nMonth
        Case 1, 5, 8, 10, 12 ' 30 day months
          nMonthLen = 30
        Case 4, 7, 9, 11, 13 ' 29 day months
          nMonthLen = 29
        Case 6 ' There is only an Adar A on a leap years
          nMonthLen = IIf(bLeap, 30, 0)
        Case 2 ' Cheshvan, see note above
          nMonthLen = IIf(bShalem, 30, 29)
        Case 3 ' Kislev, see note above
          nMonthLen = IIf(bHaser, 29, 30)
      End Select
      dGreg = dGreg.AddDays(nMonthLen)
    Next
    dGreg = dGreg.AddDays(nDateH - 1)
    Return dGreg
  End Function

  ' This function converts a Gregorian date into the Hebrew date.  The
  ' function returns the hebrew month as a string in the format MM/DD/YYYY.
  ' Also, the parameters nYearH, nMonthH and hDateH, which are sent by
  ' reference, will get set the Hebrew year, month and date. See function
  ' HebToGreg() for the definition of the month numbers.
  Public Function GregToHeb(ByVal dGreg As Date, _
                            ByRef nYearH As Integer, _
                            ByRef nMonthH As Integer, _
                            ByRef nDateH As Integer) As String
    Dim nOneMolad As Double
    Dim nAvrgYear As Double
    Dim nDays As Integer
    Dim dTishrei1 As Date
    Dim nLengthOfYear As Integer
    Dim bLeap As Boolean
    Dim bHaser As Boolean
    Dim bShalem As Boolean
    Dim nMonthLen As Integer
    Dim bWhile as Boolean

    ' The basic algorythm to get Hebrew date for the Gregorian date dGreg.
    ' 1) Find out how many days dGreg is after creation.
    ' 2) Based on those days, estimate the Hebrew year
    ' 3) Now that we a good estimate of the Hebrew year, use brute force to
    '    find the Gregorian date for Tishrei 1 prior to or equal to dGreg
    ' 4) Add to Tishrei 1 the amount of days dGreg is after Tishrei 1

    ' Figure out how many days are in a month.
    ' 29 days + 12 hours + 793 chalakim
    nOneMolad = 29 + (12 / 24) + (793 / (1080 * 24))
    ' Figure out the average length of a year. The hebrew year has exactly
    ' 235 months over 19 years.
    nAvrgYear = nOneMolad * (235 / 19)
    ' Get how many days dGreg is after creation. See note as to why I
    ' use 1/1/1900 and add 2067025
    nDays = dGreg.Subtract(#1/1/1900#).Days
    nDays += 2067025 ' 2067025 days after creation

    ' Guess the Hebrew year. This should be a pretty accurate guess.
    nYearH = Int(CDbl(nDays) / nAvrgYear) + 1
    ' Use brute force to find the exact year nYearH. It is the Tishrei 1 in
    ' the year <= dGreg.
    dTishrei1 = Tishrei1(nYearH)
    If dTishrei1 = dGreg Then
      ' If we got lucky and landed on the exact date, we can stop here
      nMonthH = 1
      nDateH = 1
    Else
      ' Here is the brute force.  Either count up or count down nYearH
      ' until Tishrei 1 is <= dGreg.
      If dTishrei1 < dGreg Then
        ' If Tishrei 1, nYearH is less than dGreg, count nYearH up.
        Do While Tishrei1(nYearH + 1) <= dGreg
          nYearH += 1
        Loop
      Else
        ' If Tishrei 1, nYearH is greater than dGreg, count nYearH down.
        nYearH -= 1
        Do While Tishrei1(nYearH) > dGreg
          nYearH -= 1
        Loop
      End If

      ' Subtract Tishrei 1, nYearH from dGreg. That should leave us with
      ' how many days we have to add to Tishrei 1
      nDays = dGreg.Subtract(Tishrei1(nYearH)).Days

      ' Find out what type of year it is so that we know the length of the
      ' months
      nLengthOfYear = LengthOfYear(nYearH)
      bHaser = nLengthOfYear = 353 Or nLengthOfYear = 383
      bShalem = nLengthOfYear = 355 Or nLengthOfYear = 385
      bLeap = IsLeapYear(nYearH)

      ' Add nDays to Tishrei 1.
      nMonthH = 1
      Do
        Select Case nMonthH
          Case 1, 5, 8, 10, 12 ' 30 day months
            nMonthLen = 30
          Case 4, 7, 9, 11, 13 ' 29 day months
            nMonthLen = 29
          Case 6 ' Adar A (6) will be skipped on non-leap years
            nMonthLen = 30
          Case 2 ' Cheshvan, see note above
            nMonthLen = IIf(bShalem, 30, 29)
          Case 3 ' Kislev, see note above
            nMonthLen = IIf(bHaser, 29, 30)
        End Select
        If nDays >= nMonthLen Then
          bWhile = True
          If bLeap Or nMonthH <> 5 Then
            nMonthH += 1
          Else
            ' We can skip Adar A (6) if its not a leap year
            nMonthH += 2
          End If
          nDays -= nMonthLen
        else
          bWhile = False
        End If
      Loop While bWhile
      ' Add the remaining days to Date
      nDateH = nDays + 1
    End If
    Return CStr(nMonthH) & "/" & CStr(nDateH) & "/" & CStr(nYearH)
  End Function

End Module

Sample HTML/Java Script Code

VB6 Version

Return to Daf-A-Week 1